.nolist
.include "m16def.inc"
.list

;up/down counter example
;use external interrupts to change the counter value
;counter/timer to debounce switches

;settings assume a 4 MHz clock
;LED's on Port B
;Switches on Port D (2 and 3)

jmp reset
jmp increase	;int0
jmp decrease	;int1
.org OVF0addr
jmp reenablebuttons	;timer/counter0 overflow

;Interrupt handler (OVF0)
;occurs 10 msec after a switch press or release
reenablebuttons:
	push r16
	in r16, SREG
	push r16

	in r16, GICR
	sbr r16, (1<<INT0)|(1<<INT1)
	out GICR, r16	;re-enable ext interrupts
	out GIFR, r16	;clear flags set during 10 msec blackout

   	ldi r16, 0<<CS00	;stop timer
   	out TCCR0, r16
	
	pop r16	
	out SREG, r16
	pop r16
	reti

stopinterrupts:
	push r16
	in r16, GICR
	cbr r16, (1<<INT0)|(1<<INT1)
	out GICR, r16	;disable both external interrupts
	pop r16
	ret

starttimer:
	push r16
	ldi r16, 100
	out TCNT0, r16	;set counter value for 10 msec to overflow
	ldi r16, 1<<TOIE0
   	out TIMSK, r16	;enable overflow interrupt
   	ldi r16, 4<<CS00
   	out TCCR0, r16	;start the timer with correct prescale
	pop r16
	ret

;Interrupt handler (INT0)
;Process switch up/down events
;Disable external interrupts to ignore bounce
;Setup timer to re-enable interrupts after bounce interval
increase:
	push r30
	in r30, SREG
	push r30
	push r31

	;if (sw sense is negative edge)
	in r30, MCUCR
	andi r30, (0b11<<ISC00)
	cpi r30, (0b10<<ISC00)
	brne increase_else
	;	switch down event
		inc count
		rjmp increase_endif
	;else
increase_else:
	;	switch up event
increase_endif:
	ldi r31, (0b01<<ISC00)
	in r30, MCUCR
	eor r30, r31	;toggle the sense control
	out MCUCR, r30

	rcall stopinterrupts
	rcall starttimer

	pop r31
	pop r30
	out SREG, r30
	pop r30
	reti

;Interrupt handler (INT1)
;Process switch up/down events
;Disable external interrupts to ignore bounce
;Setup timer to re-enable interrupts after bounce interval
decrease:
	push r30
	in r30, SREG
	push r30
	push r31

	;if (sw sense is negative edge)
	in r30, MCUCR
	andi r30, (0b11<<ISC10)
	cpi r30, (0b10<<ISC10)
	brne decrease_else
	;	switch down event
		rjmp decrease_endif
	;else
decrease_else:
		dec count
	;	switch up event
decrease_endif:
	ldi r31, (0b01<<ISC10)
	in r30, MCUCR
	eor r30, r31	;toggle the sense control
	out MCUCR, r30

	rcall stopinterrupts
	rcall starttimer

	pop r31
	pop r30
	out SREG, r30
	pop r30
	reti

reset:
	ldi r16, high(RAMEND)
	out SPH, r16
	ldi r16, low(RAMEND)
	out SPL, r16

;00 = low level; 01 = change; 10 negative edge; 11 = positive edge
	ldi r16, (0b10<<ISC10)|(0b10<<ISC00)
	out MCUCR, r16

	in r16, GICR	;enable external interrupts 
	sbr r16, (1<<INT0)|(1<<INT1)
	out GICR, r16

	ldi r16, $FF	;LED's
	out PORTB, r16
	out DDRB, r16

.def count = r16
.def temp = r17
	ldi count, 0
	sei
;Display current value of count forever
lp:
	mov temp, count
	com temp
	out PORTB, temp
	rjmp lp